universe/home/stylix/default.nix

{
  pkgs,
  config,
  ...
}: let
  enableLutgen = false;
in {
  dconf.settings = {
    "org/gnome/desktop/wm/preferences" = {
      button-layout = ":";
    };
    "org.gnome.desktop.interface" = {
      gtk-color-scheme = "prefer-dark";
      color-scheme = "prefer-dark";
    };
  };

  home.pointerCursor = {
    gtk.enable = true;
    x11.enable = true;
  };

  gtk = {
    enable = true;

    iconTheme = {
      package = pkgs.papirus-icon-theme;
      name = "Papirus-Dark";
    };
  };

  qt = {
    # platformTheme.name = lib.mkForce "gtk3";
    enable = true;
  };

  stylix = {
    enable = true;
    base16Scheme = "${pkgs.base16-schemes}/share/themes/gruvbox-material-dark-medium.yaml";
    image =
      if enableLutgen
      then let
        input = ./wallpapers.jpg;
        level = 10;
        lum = 1.0;
        preserve = false;
      in
        pkgs.runCommand "output.png" {} ''
          ${pkgs.lutgen}/bin/lutgen apply ${input} -l ${builtins.toString level} -L ${builtins.toString lum} ${
            if preserve == true
            then "-P"
            else ""
          } -o $out -- ${
            builtins.concatStringsSep " " (with config.lib.stylix.colors; [
              base00
              base01
              base02
              base03
              base04
              base05
              base06
              base07
              base08
              base09
              base0A
              base0B
              base0C
              base0D
              base0E
              base0F
            ])
          }
        ''
      else ./wallpapers.jpg;

    polarity = "dark";

    cursor = {
      package = pkgs.bibata-cursors;
      name = "Bibata-Modern-Classic";
      size = 24;
    };

    fonts = {
      serif = {
        name = "Cantarell";
        package = pkgs.cantarell-fonts;
      };
      monospace = {
        name = "CaskaydiaCove Nerd Font Mono";
        package = pkgs.nerd-fonts.jetbrains-mono;
      };
      sansSerif = config.stylix.fonts.serif;
      emoji = config.stylix.fonts.serif;

      sizes = {
        desktop = 12;
        applications = 12;
        popups = 12;
        terminal = 16;
      };
    };

    opacity = {terminal = 0.65;};

    targets = {
      kde.enable = false;
      waybar.enable = false;
      vesktop.enable = true;
    };
  };
}